PalaceChat RBScript Compendium

Script Name:	Floating Cloud
Author:	Janus.pchat
Sections:	ROOM SCRIPT
Attachments:	clouds.zip

Randomly floating cloud in the room, put this into a door and set a picture on state 1.

;START_ONENTER
	setspotstatelocal spotid, 1
	globalvar("cloud" + str( spotid ) + "x" ) = roomwidth
	globalvar("cloud" + str( spotid ) + "y" ) = roomheight
	globalvar("cloud" + str( spotid ) + "dx" ) = 0
	globalvar("cloud" + str( spotid ) + "dy" ) = 0
	setalarm 0, spotid
;END_ONENTER

;START_ONALARM
	dim d, x, y as integer
	x = globalvar( "cloud" + str( spotid ) + "x" )
	x = x + globalvar( "cloud" + str( spotid ) + "dx" )
	y = globalvar( "cloud" + str( spotid ) + "y" )
	y = y + globalvar( "cloud" + str( spotid ) + "dy" )
	
	if x < roomwidth\2\1 * -1 or y < roomheight\2\1 * -1 or x >= roomwidth\2\1 or y >= roomheight\2\1 then
		d = ((rnd*15)\1)+10
		x = roomwidth\2\1
		
		if rnd*2\1 <> 0 then
			x = x * -1
		else
			d = d * -1
		end if
		
		globalvar( "cloud" + str( spotid ) + "dx" ) = d
		
		d = ((rnd*15)\1)+10
		y = roomheight\2\1
		
		if rnd*2\1 <> 0 then
			y = y * -1
		else
			d = d * -1
		end if
		
		globalvar( "cloud" + str( spotid ) + "dy" ) = d
	end if
	
	setpicloclocal spotid, x, y
	
	globalvar( "cloud" + str( spotid ) + "x" ) = x
	globalvar( "cloud" + str( spotid ) + "y" ) = y
	
	if spotstate( spotid ) <> 0 then
		setalarm ( rnd * 550 ) + 550, spotid
	end if
;END_ONALARM